home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #2 / Ham Radio 2000 - Volume 2.iso / HAMV2 / MISC / HCAL-27 / MOBILMAT.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1997-01-29  |  2.4 KB  |  99 lines
  1. 10  'MOBILMAT - Mobile Antenna Matching - 08 APR 96 rev.11 NOV 96
  2. 20  IF EX$=""THEN EX$="EXIT"
  3. 30  CLS:KEY OFF
  4. 40  COLOR 7,0,1
  5. 50  PI=3.14159
  6. 60  UL$=STRING$(80,205)
  7. 70  U$="#####.###"
  8. 80  '
  9. 90  COLOR 15,2
  10. 100  PRINT " MOBILE ANTENNA MATCHING";TAB(57)"by George Murphy VE3ERP ";
  11. 110  COLOR 1,0:PRINT STRING$(80,223);
  12. 120  COLOR 7,0
  13. 130  GOTO 200
  14. 140  '
  15. 150  '.....format input line
  16. 160  LOCATE CSRLIN-1:PRINT SPC(7);
  17. 170  LOCATE CSRLIN,47:PRINT STRING$(7,".");USING U$;ZZ;
  18. 180  RETURN
  19. 190  '
  20. 200  '.....start
  21. 210  GOSUB 530
  22. 220  PRINT UL$;
  23. 230  '
  24. 240  GOSUB 680
  25. 250  LOCATE 20,24:COLOR 0,7
  26. 260  PRINT " Press 1 to continue or 0 to EXIT "
  27. 270  COLOR 7,0
  28. 280  Z$=INKEY$:IF Z$=""THEN 280
  29. 290  IF Z$="0"THEN CLS:RUN EX$
  30. 300  IF Z$="1"THEN 330
  31. 310  GOTO 280
  32. 320  '
  33. 330  '.....data input
  34. 340  VIEW PRINT 14 TO 24:CLS:VIEW PRINT:LOCATE 14
  35. 350  INPUT " ENTER: Frequency of operation..................(MHz)";Z
  36. 360  ZZ=Z:GOSUB 150:PRINT " MHz"
  37. 370  F=Z*10^3
  38. 380  '
  39. 390  INPUT " ENTER: Antenna Feedpoint Resistance...........(ohms)";RA
  40. 400  ZZ=RA:GOSUB 150:PRINT " ohms"
  41. 410  '
  42. 420  INPUT " ENTER: Characteristic Impedance of Feedline...(ohms)";ZO
  43. 430  ZZ=ZO:GOSUB 150:PRINT " ohms"
  44. 440  '
  45. 450  C1=SQR(RA*(ZO-RA))/(2*PI*F*RA*ZO)*10^9
  46. 460  L1=SQR(RA*(ZO-RA))/(2*PI*F)*10^3
  47. 470  PRINT "        Capacitance C1...............................";USING U$;C1;
  48. 480  PRINT " pF"
  49. 490  PRINT "        Inductance L1................................";USING U$;L1;
  50. 500  PRINT " >H"
  51. 510  GOTO 810
  52. 520  '
  53. 530  '.....diagram
  54. 540  T=27:COLOR 0,7
  55. 550  LOCATE ,T:PRINT "                            "
  56. 560  LOCATE ,T:PRINT "                         CALL  "
  57. 570  LOCATE ,T:PRINT "        resonant whip SOUNDSOUNDDEFDBLCALL  "
  58. 580  LOCATE ,T:PRINT "                         CALL  "
  59. 590  LOCATE ,T:PRINT "              VARPTRSOUNDSOUNDSOUNDBSAVESOUNDORORORORSOUND'  "
  60. 600  LOCATE ,T:PRINT "  coaxial THENTHENTHENFNLOAD   CALL  L1     "
  61. 610  LOCATE ,T:PRINT "  feedline   BLOADSOUND<0xB4!>BLOADSOUND'         "
  62. 620  LOCATE ,T:PRINT "             CALL C1           "
  63. 630  LOCATE ,T:PRINT "   vehicle \\MOTOR\\ body       "
  64. 640  LOCATE ,T:PRINT "                            "
  65. 650  COLOR 7,0
  66. 660  RETURN
  67. 670  '
  68. 680  '.....preface
  69. 690  T=8
  70. 700  PRINT TAB(T);
  71. 710  PRINT "Any resonant mobile antenna that has a feed-point impedance less"
  72. 720  PRINT TAB(T);
  73. 730  PRINT "than the characteristic impedance of the transmission line can be"
  74. 740  PRINT TAB(T);
  75. 750  PRINT "matched to the line by means of a simple L-network as shown above."
  76. 760  PRINT
  77. 770  PRINT TAB(T);
  78. 780  PRINT "(The 1997 ARRL HANDBOOK for RADIO AMATEURS, pages 20.46 & 20.47)"
  79. 790  RETURN
  80. 800  '
  81. 810  '.....end
  82. 820  GOSUB 860
  83. 830  VIEW PRINT 14 TO 24:CLS:VIEW PRINT:LOCATE 14:GOTO 240
  84. 840  END
  85. 850  '
  86. 860  'HARDCOPY
  87. 870  GOSUB 980:LOCATE 25,2:COLOR 14,6
  88. 880  PRINT " Press 1 to print screen, 2 to print screen & ";
  89. 890  PRINT "advance paper, or 3 to continue.";:COLOR 7,0
  90. 900  Z$=INKEY$:IF Z$="3"THEN GOSUB 980:RETURN
  91. 910  IF Z$="1"OR Z$="2"THEN GOSUB 980:GOTO 930
  92. 920  GOTO 900
  93. 930  FOR QX=1 TO 24:FOR QY=1 TO 80
  94. 940  LPRINT CHR$(SCREEN(QX,QY));
  95. 950  NEXT QY:NEXT QX
  96. 960  IF Z$="2"THEN LPRINT CHR$(12)
  97. 970  GOTO 870
  98. 980  LOCATE 25,1:PRINT STRING$(80,32);:RETURN
  99.